excel中的条件函数怎么用
方法/步骤
1
首先我们打开一个excle表格。
2
在excle表格里面，我们添加了一些数据，关于语文和数学的成绩汇总，最后一栏是等级的统计，现在我们想要对等级进行划分，语文和数学都大于80分的被评为优，否则被评为差。
3
我们选中E2这个单元格，也就是我们计算序号为1的这位同学的成绩等级。
4
接着我们在函数的输入区域里面，先输入=IF(),这是写所有IF函数的开头，IF函数使用多个条件的格式：=IF(条件，满足条件时的值，不满足条件时的值)。
5
然后我们先来写条件，我们使用AND函数将多个条件组合起来。AND(B2>=80,C2>=80)表示这两个条件都需要满足。
6
接着我们写满足时和不满足时的值，当条件都满足时，值为“优”，当不满足时，值“差”。
7
最后我们按下回车键，这时候，E2就显示了一个“差”的等级，因为语文和数学都没有大于等于80，所以条件不满足，等级为“差”。
8
最后剩下的同学的等级我们不必重新再计算了，鼠标选中E2这个单元格，当鼠标呈现“+”字样的时候，往下拉，这时候，其他同学的等级就出来了。
Excel CountIf函数的用法和语法，含多个条件的示例
一、Countif函数怎么用
(一)统计指定文字个数
1、假如要统计“小类”中“T恤”的个数。选中 C13 单元格，输入公式 =COUNTIF(C2:C12,"T恤")，按回车，返回统计结果 4;操作过程步骤，如图1所示：
2、公式说明：公式 =COUNTIF(C2:C12,"T恤") 中“统计范围”为 C2:C12，条件为“T恤”，也就是说单文字也可以作为条件。
(二)用 >= 或 < 组合条件
1、假如要统计价格大于等于 90 的服装件数。把公式 =COUNTIF(E2:E12,">=90") 复制到 E13 单元格，按回车，返回统计结果为 6，操作过程步骤，如图2所示：
2、公式中的条件 ">=90" 也可以这样写：">="&90。如果要统计价格小于等于 90 的服装件数，公式可以这样写：=COUNTIF(E2:E12,"<="&90)，如图3所示：
按回车，统计结果返回 5，如图4所示：
如果要统计价格不等于 90 的服装件数，只需把公式 =COUNTIF(E2:E12,">=90") 条件中的 >= 改为 <>，则公式变为 =COUNTIF(E2:E12,"<>90")。
(三)用通配符问号与星号组合条件
假如要统计以“衬衫”结尾的服装件数;把公式 =COUNTIF(B2:B12,"*衬衫") 复制到 B13 单元格，按回车，返回结果 5。假如要统计以“粉红”开头的服装件数，把公式 =COUNTIF(B2:B12,"粉红*") 复制到 B13 单元格，按回车，返回统计结果 2。假如要统计名称为四个字的服装件数，把公式 =COUNTIF(B2:B12,"????") 复制到 B13，按回车，返回统计结果 8。假如要统计“前面四个字 + T恤”组合的服装名称，把公式 =COUNTIF(B2:B12,"????T恤") 复制到 B13，按回车，返回统计结果 1;操作过程步骤，如图5所示：
(四)CountIf 与 Average 组合使用
1、假如要统计大于平均销量的服装件数。把公式 =COUNTIF(F2:F12,">"&AVERAGE(F2:F12)) 复制到 F13 单元格，如图6所示：
2、按回车，返回结果 5。
3、公式说明：公式 =COUNTIF(F2:F12,">"&AVERAGE(F2:F12)) 中条件为 ">"&AVERAGE(F2:F12)，AVERAGE 是求平均值函数，条件的意思是：求大于服装销量的平均值。
二、CountIf函数用数组组合多重条件的使用实例
1、假如要统计销量大于等于 350 且小于等于 750 的服装件数。把公式 =SUM(COUNTIF(F2:F12,{">=350",">750"})*{1,-1}) 复制到 F13 单元格，按回车，则返回统计结果 4;操作过程步骤，如图7所示：
2、公式说明：CountIf 中的条件 {">=350",">750"} 是一个数组，数组中包含两个条件，一个是 ">=350"，另一个是 ">750"，这里要求的是 <= 750，为何第二个条件是 >750?这决定于 CountIF 的计算顺序，它先统计 F2:F12 中满足第一个条件(>=350)的服装件数(结果为 8)，再统计满足第二个条件(>750)服装件数(结果为 4)，然后再把两个结果加起来，这样结果为 12，显然不对，因此后面再加 *{1,-1}，这样用第一个条件的统计结果 8 * 1，用第二个条件的统计结果 4 * -1，再把两个结果相加，即 8-4，最终等于 4;公式求值过程，如图8所示：
3、其它数组组合条件分别如下：
A、大于 350 且小于 750：=SUM(COUNTIF(F2:F12,{">350",">=750"})*{1,-1})
B、大于等于 350 且小于 750：=SUM(COUNTIF(F2:F12,{">=350",">=750"})*{1,-1}) 或 =SUM(COUNTIF(F2:F12,">="&{350,750})*{1,-1})
C、大于 350 且小于等于 750：=SUM(COUNTIF(F2:F12,{">350",">750"})*{1,-1}) 或 =COUNTIF(F2:F12,">350")- COUNTIF(F2:F12,">750")
三、CountIf函数语法
1、表达式：COUNTIF(Range, Criteria)
中文表达式：COUNTIF(统计范围, 条件)
2、说明：
A、条件不能超过 255 个字符，否则会返回错误。
B、统计文本个数时，不能包含前导空格与尾部空格，也不能出现直引号与弯引号不一致和非打印字符;否则，可能返回不可预期的值。
C、在条件中可以使用通配符问号(?)和星号(*)，问号表示任意一个字符，星号表示一个或一串字符;如果要查找问号或星号，需要在它们前面加转义字符~，例如查找问号，表达式应该这样写 ~?。
